MySensors - Gateway to Domoticz

[Hendrik]

For example sketches look here: http://www.domoticz.com/forum/viewtopic.php?f=42&t=5837

I know this site, but i have a lot of struggle with my watermeter, and with the 1-wire temp sketch
My plan is to make a sensor with two temp sensors and a relay.
but when you have a working sketch, please post it, so whe can learn from it

[gizmocuz]

I guess you can use the 5 custom variables to store/read custom things ? Like your last counter values?

Like in the original 'EnergyMeterPulseSensor.ino' sketch ?

As I said: would be possible to use the custom variables like the example sketch is doing. But why construct a workaround when a dedicated route is in place. But if that is what it is..

To have the Energy value updated in Domoticz:

From the MySensors sketch:
1. Present an "Energy meter" (kWh, Wh sensors) to Domoticz
2. Present V_VAR1 to Domoticz

Loop:
3. Read V_VAR1 from Domoticz (= total usage in Wh) = Actual usage in Domoticz
4. Add Wh to V_VAR1
5. Write V_VAR1 to Domoticz
6. Write V_KWH and V_WATT to Domoticz

- --- or ----

From the MySensors sketch:
1. Present an "Energy meter" (kWh, Wh sensors) to Domoticz

Loop:
2. Read V_KWH from Domoticz (= total usage in Wh) = Actual usage in Domoticz
3. Add Wh to V_KWH
4. Write V_KWH and V_WATT to Domoticz

Come on... use the VAR type to store/request your backups

[gizmocuz]

For example sketches look here: http://www.domoticz.com/forum/viewtopic.php?f=42&t=5837

I know this site, but i have a lot of struggle with my watermeter, and with the 1-wire temp sketch
My plan is to make a sensor with two temp sensors and a relay.
but when you have a working sketch, please post it, so whe can learn from it

think you have more success on the mysensors forum ?

[floris74]

I think sending normal 'V_LIGHT' commands should work

probably, but i don't know where to write that in the sketch. I tries te change the S_LIGHT. but that didn't work..

[gizmocuz]

I think sending normal 'V_LIGHT' commands should work

probably, but i don't know where to write that in the sketch. I tries te change the S_LIGHT. but that didn't work..

Try to create a test sketch, where you print debug messages to the serial console

make a loop that sends a switch on/off, and handle incoming messages

If you do not know how todo this, ask this in the mysensors forum, this seems not a topic for in here.

[floris74]

Ok, ill try, basicly using the provided skech from mysensors.

[gizmocuz]

provided sketches are just examples.

best to write your own (based on an existing one), and first test without hardware (maybe sending some random things),
and do a lot of debug serial prints
when this is working, start implementing the real hardware

mysensors is not copy/paste

but maybe this can help as example

Code: Select all

/***
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * version 2 as published by the Free Software Foundation.
 * 
 * DESCRIPTION
 * This sketch provides an example how to implement a Dimmable Light 
 * It is pure virtual and it logs messages to the serial output
 * It can be used as a base sketch for actual hardware
 * 
 * Developed by GizMoCuz (Domoticz)
 *
 * REVISION HISTORY
 * Version 1.0 - January 30, 2015
 *
 ***/
 
#include <SPI.h>
#include <MySensor.h>  

#define CHILD_ID_LIGHT 1

#define EPROM_LIGHT_STATE 1
#define EPROM_DIMMER_LEVEL 2

#define LIGHT_OFF 0
#define LIGHT_ON 1

#define SN "Dimable Light Example"
#define SV "1.0"

int LastLightState=LIGHT_OFF;
int LastDimValue=100;

MySensor gw;
MyMessage lightMsg(CHILD_ID_LIGHT, V_LIGHT);
MyMessage dimmerMsg(CHILD_ID_LIGHT, V_DIMMER);

void setup()  
{ 
  gw.begin(incomingMessage, AUTO, false);

  // Send the Sketch Version Information to the Gateway
  gw.sendSketchInfo(SN, SV);

  gw.present(CHILD_ID_LIGHT, S_DIMMER );

  //Retreive our last light state from the eprom
  int LightState=gw.loadState(EPROM_LIGHT_STATE); 
  if (LightState<=1) {
    LastLightState=LightState;
    int DimValue=gw.loadState(EPROM_DIMMER_LEVEL); 
    if ((DimValue>0)&&(DimValue<=100)) {
      //There should be no Dim value of 0, this would mean LIGHT_OFF
      LastDimValue=DimValue;
    }
  }

  //Here you actualy switch on/off the light with the last known dim level
  SetCurrentState2Hardware();
  
  Serial.println( "Node ready to receive messages..." );  
}

void loop()      
{
  // Process incoming messages
  gw.process();
}

void incomingMessage(const MyMessage &message)
{
  if (message.type == V_LIGHT) {
    Serial.println( "V_LIGHT command received..." );
    
    int lstate= atoi( message.data );
    if ((lstate<0)||(lstate>1)) {
      Serial.println( "V_LIGHT data invalid (should be 0/1)" );
      return;
    }
    LastLightState=lstate;
    gw.saveState(EPROM_LIGHT_STATE, LastLightState);
    
    if ((LastLightState==LIGHT_ON)&&(LastDimValue==0)) {
       //In the case that the Light State = On, but the dimmer value is zero,
       //then something (probably the controller) did something wrong,
       //for the Dim value to 100%
      LastDimValue=100;
      gw.saveState(EPROM_DIMMER_LEVEL, LastDimValue);
    }
    
    //When receiving a V_LIGHT command we switch the light between OFF and the last received dimmer value
    //This means if you previously set the lights dimmer value to 50%, and turn the light ON
    //it will do so at 50%
  }
  else if (message.type == V_DIMMER) {
    Serial.println( "V_DIMMER command received..." );  
    int dimvalue= atoi( message.data );
    if ((dimvalue<0)||(dimvalue>100)) {
      Serial.println( "V_DIMMER data invalid (should be 0..100)" );
      return;
    }
    if (dimvalue==0) {
      LastLightState=LIGHT_OFF;
    }
    else {
      LastLightState=LIGHT_ON;
      LastDimValue=dimvalue;
      gw.saveState(EPROM_DIMMER_LEVEL, LastDimValue);
    }
  }
  else {
    Serial.println( "Invalid command received..." );  
    return;
  }

  //Here you set the actual light state/level
  SetCurrentState2Hardware();
}

void SetCurrentState2Hardware()
{
  if (LastLightState==LIGHT_OFF) {
     Serial.println( "Light state: OFF" );
  }
  else {
     Serial.print( "Light state: ON, Level: " );
     Serial.println( LastDimValue );
  }

  //Send current state to the controller
  SendCurrentState2Controller();
}

void SendCurrentState2Controller()
{
  if ((LastLightState==LIGHT_OFF)||(LastDimValue==0)) {
    gw.send(dimmerMsg.set(0));
  }
  else {
    gw.send(dimmerMsg.set(LastDimValue));
  }
}

[slasklitta]

Hey guys!

So I got a bunch of Arduinos and sensors today.
- Got the Gateway up and running on a Nano
- Gateway hooked up to Raspberry Pi 2 running Domoticz(correct usb port added in hardware)
- A temperature sensor hooked up to a Uno.

But the gateway doesn't seem to find the node. I tried hooking it up to MYSController on Windows but no luck there either.
Yes, I've checked the wiring several times.

This is the temp sensor i got: http://www.aliexpress.com/snapshot/6518 ... 5012169718
Its hooked up from DQ to pin 3. VCC to 5V and GND to GND

Did a blink test on both devices. Worked like a charm.
Also, I'm new to Mysensors and Arduino. But I'm a fast learner

[ThinkPad]

Welcome to this forum

Try powering the nRF24L01+ on the gateway and nodes with an external 3.3V powersupply. I also had difficulties where the gateway didn't receive the nodes.
Gave the nRF's power with an external 3.3V and it worked great.

Best is to try with MYSController indeed, you can see all the messages flying by there, more information than in Domoticz

[slasklitta]

Welcome to this forum

Try powering the nRF24L01+ on the gateway and nodes with an external 3.3V powersupply. I also had difficulties where the gateway didn't receive the nodes.
Gave the nRF's power with an external 3.3V and it worked great.

Best is to try with MYSController indeed, you can see all the messages flying by there, more information than in Domoticz

Thanks man!

Hmm. External power.
I Don't know if I have a power supply with 3.3v
Shouldn't I get some sort of error if the radio isn't getting enough power?

I'll replace all the radios and temp sensor tomorrow

[pendragon]

That is right if the voltage is way different from the desired 3.3v.
I had the problem with an 2560 where the serial output of the arduino gave me the message :"check wires"


What does the serial output of the controller tell you?

[gizmocuz]

[..]
Have you used the latest sketch?

And the latest beta of domoticz ?

It should send an empty value back, i supposed that would be translated to '0'

Code: Select all

		case V_VAR1:
		case V_VAR2:
		case V_VAR3:
		case V_VAR4:
		case V_VAR5:
			//send back a previous stored custom variable
			tmpstr = "";
			GetVar(node_id, child_sensor_id, sub_type, tmpstr);
			SendCommand(node_id, child_sensor_id, message_type, sub_type, tmpstr);
			break;

Maybe mysensors does not like an empty value, please tell if you are using the latest beta of domoticz, if yes, i will modify domoticz to send '0' back

Domoticz 2336 i thought, with sketch from MySensors page (updated by you, 23 march). I think it doesn't like a empty value indeed.

But i stop with the watermeter, it is too much hassle, and water is too cheap to monitor this. Creates a lot of frustration to get everything working haha But not stopping with MySensors, i am planning on creating a few cheap temperature / humidity sensors to place in different rooms.

Double checked, when there is not yet a value in domoticz (V_VAR1), it sends an empty string, this is translated to 0, so it should work.
Maybe your domoticz version was not the latest

Code: Select all

sensor started, id 2
send: 2-2-0-0 s=255,c=0,t=17,pt=0,l=5,st=ok:1.4.1
send: 2-2-0-0 s=255,c=3,t=6,pt=1,l=1,st=ok:0
read: 0-0-2 s=255,c=3,t=6,pt=0,l=1:M
send: 2-2-0-0 s=255,c=3,t=11,pt=0,l=11,st=ok:Water Meter
send: 2-2-0-0 s=255,c=3,t=12,pt=0,l=3,st=ok:1.2
send: 2-2-0-0 s=1,c=0,t=21,pt=0,l=5,st=ok:1.4.1
send: 2-2-0-0 s=1,c=2,t=24,pt=0,l=0,st=ok:
read: 0-0-2 s=1,c=2,t=24,pt=0,l=1:
[b]Received last pulse count from gw:0[/b]
l/min:6.74
send: 2-2-0-0 s=1,c=1,t=34,pt=7,l=5,st=ok:6.74
pulsecount:1
send: 2-2-0-0 s=1,c=1,t=24,pt=5,l=4,st=ok:1
volume:0.001
send: 2-2-0-0 s=1,c=1,t=35,pt=7,l=5,st=ok:0.001

[ThinkPad]

Thanks for checking. I was using 2336, now updating to 2339.
But i am not gonna use the watermeter sketch anymore, too frustrating to get the sensor aligned on my meter.

I am sure the sketch is useful for someone else though..!

Welcome to this forum

Try powering the nRF24L01+ on the gateway and nodes with an external 3.3V powersupply. I also had difficulties where the gateway didn't receive the nodes.
Gave the nRF's power with an external 3.3V and it worked great.

Best is to try with MYSController indeed, you can see all the messages flying by there, more information than in Domoticz

Thanks man!

Hmm. External power.
I Don't know if I have a power supply with 3.3v
Shouldn't I get some sort of error if the radio isn't getting enough power?

I'll replace all the radios and temp sensor tomorrow

When powering the nRF directly from the Arduino Nano i saw a lot of 'st=fail' in the serial console. That means a communication problem with the nRF or so... when i applied an external 3.3V powersource it said 'st=ok'

[AWI]

A lot has been written on the MySensors forum on this subject. It boils down to a very stable power supply for the radio. What works in most cases is a capacitor direcly on the radio of > 4.7uF, I use 47uF for a normal (non amplified) nRF24l01+. The radio is very sensitive to any disturbance in the power supply. An arduino uno/nano should be able to power the radio (from 3.3v) when the capacitor is applied.

[raditiya]

Multibutton, Mutirelay in one node.

I have a problem with Domoticz software for multibutton/multirelay, the serial ouput is fine, gateway get ack and reply. but when I press the button, Domoticz isn't responding (sometimes responding), I don't think that is radio problem because serial output is fine. maybe the problem with the software.

below is the sketch from AWI

Code: Select all

 
#include <MySensor.h>
#include <SPI.h>
#include <Bounce2.h>
#define RELAY_ON 1 //switch around for realy HIGH/LOW state
#define RELAY_OFF 0
//
MySensor gw;

#define noRelays 4
const int relayPin[] = {7, 8, A0, A1};
const int buttonPin[] = {3, 4, 5, 6};

class Relay							// relay class, store all relevant data (equivalent to struct)
{
public:                             		 
  int buttonPin;					// physical pin number of button
  int relayPin;						// physical pin number of relay
  byte oldValue;               		// last Values for key (debounce)
  boolean relayState;             	// relay status (also stored in EEPROM)
};

Relay Relays[noRelays];	
Bounce debouncer[noRelays];
MyMessage msg[noRelays];

void setup(){
	gw.begin(incomingMessage, AUTO, false);
	delay(250);
	gw.sendSketchInfo("MultiRelayButton", "0.9b");
	delay(250);
	// initialize Relays with corresponding buttons
	for (int i = 0; i < noRelays; i++){
		Relays[i].buttonPin = buttonPin[i];				// assign physical pins
		Relays[i].relayPin = relayPin[i];
		msg[i].sensor = i;								// initialize messages
		msg[i].type = V_LIGHT;
		debouncer[i] = Bounce();						// initialize debouncer
		debouncer[i].attach(buttonPin[i]);
		debouncer[i].interval(5);
		pinMode(Relays[i].buttonPin, INPUT_PULLUP);
	//	pinMode(Relays[i].relayPin, OUTPUT);
		Relays[i].relayState = gw.loadState(i);			// retrieve last values from EEPROM
		digitalWrite(Relays[i].relayPin, Relays[i].relayState? RELAY_ON:RELAY_OFF); // and set relays accordingly
		gw.send(msg[i].set(Relays[i].relayState? true : false), true);	// make controller aware of last status
		gw.present(i, S_LIGHT);							// present sensor to gateway
		delay(250);
	}
}

void loop()
	{
	gw.process();
	for (byte i = 0; i < noRelays; i++)
		{
		debouncer[i].update();
		byte value = debouncer[i].read();
		if (value != Relays[i].oldValue && value == 0)
			{
			Relays[i].relayState = !Relays[i].relayState;
			digitalWrite(Relays[i].relayPin, Relays[i].relayState);
			gw.send(msg[i].set(Relays[i].relayState? true : false), true);
			gw.saveState( i, Relays[i].relayState ); // save sensor state in EEPROM (location == sensor number)
			}
		Relays[i].oldValue = value;
		}
	}

// process incoming message 
void incomingMessage(const MyMessage &message)
{
	if (message.isAck()){
		Serial.println(F("This is an ack from gateway"));
	}
	if (message.type == V_LIGHT){ 
		if (message.sensor <= noRelays){ 				// check if message is valid for relays
			Relays[message.sensor].relayState = message.getBool(); 
			digitalWrite(Relays[message.sensor].relayPin, Relays[message.sensor].relayState? RELAY_ON:RELAY_OFF); // and set relays accordingly
			gw.saveState( message.sensor, Relays[message.sensor].relayState ); // save sensor state in EEPROM (location == sensor number)
		}
	}
}

and this is my serial output when I pressed the button

Code: Select all

This is an ack from gateway
send: 26-26-0-0 s=0,c=1,t=2,pt=2,l=2,st=ok:1
read: 0-0-26 s=0,c=1,t=2,pt=2,l=2:1
This is an ack from gateway
send: 26-26-0-0 s=1,c=1,t=2,pt=2,l=2,st=ok:0
read: 0-0-26 s=1,c=1,t=2,pt=2,l=2:0
This is an ack from gateway
send: 26-26-0-0 s=1,c=1,t=2,pt=2,l=2,st=ok:1
read: 0-0-26 s=1,c=1,t=2,pt=2,l=2:1
This is an ack from gateway
send: 26-26-0-0 s=2,c=1,t=2,pt=2,l=2,st=ok:0
read: 0-0-26 s=2,c=1,t=2,pt=2,l=2:0
This is an ack from gateway
send: 26-26-0-0 s=2,c=1,t=2,pt=2,l=2,st=ok:1
read: 0-0-26 s=2,c=1,t=2,pt=2,l=2:1
This is an ack from gateway
send: 26-26-0-0 s=3,c=1,t=2,pt=2,l=2,st=ok:0
read: 0-0-26 s=3,c=1,t=2,pt=2,l=2:0
This is an ack from gateway
send: 26-26-0-0 s=3,c=1,t=2,pt=2,l=2,st=ok:1
read: 0-0-26 s=3,c=1,t=2,pt=2,l=2:1
This is an ack from gateway

and also if I control the relay from Domoticz it's also fine, the problem is only when I pressed the button, domoticz often not update the status.

[jovo]

I implemented in only one of my 3 mysensor nodes the battery measurment sketch (integrated in the humidity sketch).
The strange thing i see now is that all 3 sensor are reporting battery level, while only one has code for it.
I find it a bit weird and doesnt seems right.

The actual battery levels are also wrong, but thats because i didnt implement the resistors yet (i only did the software part as i had no correct resistors).
I had this problem with latest stable and i upgraded to the latest beta 2339, but it had the same effect.

Anybody any idea what to do?

[ThinkPad]

A lot has been written on the MySensors forum on this subject. It boils down to a very stable power supply for the radio. What works in most cases is a capacitor direcly on the radio of > 4.7uF, I use 47uF for a normal (non amplified) nRF24l01+. The radio is very sensitive to any disturbance in the power supply. An arduino uno/nano should be able to power the radio (from 3.3v) when the capacitor is applied.

First thing i did indeed, a 47uF capacitor soldered directly on the nRF (Vcc and GND). But still i got errors...

I also thought the Nano could deliver enough (specs say 50mA on 3.3V) because the nRF only uses 17mA at max or so...

http://www.nordicsemi.com/eng/Products/ ... F/nRF24L01

But now im thinking of it, i thought my Nano3 is not using a FTDI chip, but some cheaper one (CH340). Maybe the problem lies there, because that cheaper chip can deliver less current or so... Or it is more noisey, i read that current isn't less a problem, but more that a noisey powersupply will have a big negative impact on the nRF.

[floris74]

and the sketch underneath it (LightLuxSensor Example) uses the actual value

so whats the standard ? At the moment i have implemented it as percentage, if you convert your value in the range of 0-100% then it should work.

Standard should be to report in Lux. The only % value is V_DIMMER. I have reported it in the MySensors forum.

Great to see the implementation growing.

! Update 24-3-2015 11:03, response on MySensors forum:

Agree, this is a "bug". The problem with the current V_* is that it contains no unit information. A backward compatible solution for this for the 1.6 release would be to introduce a V_LIGHT_LEVEL_LUX. Not pretty but it solves the problem without breaking anything.

I've got the same. But how can it be solved for the moment?

[gizmocuz]

Okey, made a new beta, #2350+, with this beta you can should use the actual lux value instead of the percentage
current percentage users should convert it between 0-1000 lux

[floris74]

Hi Gizmocuz, thank you very much for fixing the lux meter!!! i'm so happy!!!!